    1 ********************************
    2 * "TYPETIME" - CHRIS TORRENCE  *
    3 * APPLESOFT AMPERSAND ROUTINE  *
    4 * TO TIME HOW LONG IT TAKES    *
    5 * TO TYPE A WORD. APRIL 2015.  *
    6 * ADAPTED FROM ROUTINES WITHIN *
    7 *       ASSEMBLY LINES:        *
    8 *      THE COMPLETE BOOK       *
    9 *       BY ROGER WAGNER        *
   10 *    EDITED BY CHRIS TORRENCE  *
   11 * USAGE: BLOAD TYPETIME,A$300  *
   12 *  10 POKE 1014,0: POKE 1015,3 *
   13 *  20 & "HELLO",A%             *
   14 *  30 PRINT A%                 *
   15 * "TIME" IS IN MILLISECONDS    *
   16 ********************************
   17          ORG  $300
   18 CHKCOM   EQU  $DEBE
   19 FRMEVL   EQU  $DD7B
   20 FRESTR   EQU  $E5FD
   21 INDEX    EQU  $5E        ; $5E,5F
   22 DATA     EQU  $3A0
   23 PTRGET   EQU  $DFE3
   24 MOVFM    EQU  $EAF9
   25 CHKNUM   EQU  $DD6A
   26 VARPNT   EQU  $83
   27 KYBD     EQU  $C000
   28 STROBE   EQU  $C010
   29 COUT     EQU  $FDED
   30 *
   31 * READ THE STRING FROM APPLESOFT
   32          JSR  FRMEVL     ; EVALUATE STRING
   33          JSR  FRESTR     ; VAR = STRING?
   34                          ; IF SO, MAKE ROOM
   35          TAY             ; PUT LENGTH IN Y
   36          LDA  #$8D       ; <RETURN>
   37          STA  DATA,Y
   38          TYA             ; LENGTH BACK TO A, SO WE CAN
   39          BEQ  INIT       ; TEST FOR AN EMPTY STRING
   40 *
   41 * STORE THE STRING IN MEMORY
   42 LOOP     DEY
   43          LDA  (INDEX),Y  ; GET CHAR FROM ADDRESS
   44                          ; CONTAINED IN $5E,5F
   45          ORA  #$80       ; TURN ON CHAR HI BIT
   46          STA  DATA,Y
   47          CPY  #$00
   48          BNE  LOOP
   49 *
   50 * TIME THE USER TYPING THE STRING
   51 INIT     LDA  #$00
   52          STA  $06        ; LOW BYTE OF TIME
   53          STA  $07        ; MIDDLE BYTE
   54          STA  $08        ; HIGH BYTE
   55          STA  $09
   56 TIME     INC  $06        ; ~60,000 COUNTS/SECOND
   57          BNE  SKIP       ; DID LOW BYTE WRAP?
   58          INC  $07
   59          BNE  SKIP       ; DID NEXT BYTE WRAP?
   60          INC  $08
   61          BNE  SKIP       ; HIGH BYTE WRAP?
   62          LDA  #$00       ; AUTOMATIC FAILURE
   63          LDY  $09        ; STORE JUNK IN "DATA"
   64          STA  DATA,Y
   65 SKIP     LDA  KYBD
   66          CMP  #$80       ; KEY PRESSED?
   67          BCC  TIME
   68          STA  STROBE     ; CLEAR KEYBOARD STROBE
   69          JSR  COUT       ; PRINT THE CHARACTER
   70          CMP  #$8D       ; IF <RETURN> THEN DONE
   71          BEQ  DONE
   72          LDY  $09
   73          CMP  DATA,Y
   74          BNE  TIME       ; WRONG CHAR PRESSED
   75          INC  $09        ; CORRECT CHAR, GO ON TO NEXT
   76          CLC             ; FORCED BRANCH (RELOCATABLE)
   77          BCC  TIME
   78 *
   79 DONE     LDY  $09
   80          LDA  DATA,Y
   81          CMP  #$8D       ; REACHED THE <RETURN>
   82          BEQ  FINISH
   83          LDA  #%11111111 ; FAILURE, RETURN MAX TIME
   84          STA  $06
   85          STA  $07
   86          LDA  #%00011111
   87          STA  $08
   88 *
   89 * PASS THE TIME INTEGER VALUE BACK TO APPLESOFT
   90 FINISH   ASL  $06        ; MULTIPLY CYCLES BY 4
   91          ROL  $07        ; TO GET TIME IN MILLISECONDS
   92          ROL  $08
   93          ASL  $06
   94          ROL  $07
   95          ROL  $08
   96          JSR  CHKCOM     ; SWALLOW COMMA
   97          JSR  PTRGET     ; FIND VARIABLE
   98 * Y,A = ADDRESS OF VALUE
   99          JSR  MOVFM      ; MOVE VAL -> FAC
  100          JSR  CHKNUM     ; FAC = NUM?
  101          LDY  #$00
  102          LDA  $08        ; HIGH BYTE FIRST
  103          STA  (VARPNT),Y
  104          INY
  105          LDA  $07
  106          STA  (VARPNT),Y
  107          RTS
  108          LST  OFF
